***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 26, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZX84B3V3 A K 
.param
+vc0 = 1.096e-12	 vc1 = 1.483e-9 	 vc2 = 1.000e0		 vc3 = 2.401e-7		 vc4 = 8.3800e0
+tc1 = 2.751e-2		 tc2 = 1.721e-2		 tc3 = 4.991e-3		 tc4 = 1.001e-4	   
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 5.176e-16 	   n = 1.008		  rs = 4.769e-1		 ikf = 1.252e-1
+ibv = 1e-3		 nbv = 1.0		  bv = 3.3
***** capacitance parameter *****
+cjo = 1.811e-10	   m = 2.617e-1		  vj = 4.959e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.135		 xti = 3
+trs1 = 9.116e-5	trs2 = 1.234e-5		tikf = 1e-3			
+tbv1 = -2.392e-4	tbv2 = -3.365e-6
.ends BZX84B3V3
*$
